Mercurial > hgrepos > Python2 > PyMuPDF

comparison mupdf-source/thirdparty/tesseract/CMakeLists.txt @ 2:b50eed0cc0ef upstream

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
ADD: MuPDF v1.26.7: the MuPDF source as downloaded by a default build of PyMuPDF 1.26.4. The directory name has changed: no version number in the expanded directory now.
author Franz Glasner <fzglas.hg@dom66.de>
date Mon, 15 Sep 2025 11:43:07 +0200
parents
children
comparison
equal deleted inserted replaced
1:1d09e1dec1d9 2:b50eed0cc0ef
1 #
2 # tesseract
3 #
4
5 # ##############################################################################
6 #
7 # cmake settings
8 #
9 # ##############################################################################
10
11 cmake_minimum_required(VERSION 3.10 FATAL_ERROR)
12
13 # In-source builds are disabled.
14 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
15 message(
16 FATAL_ERROR
17 "CMake generation is not possible within the source directory!"
18 "\n Remove the CMakeCache.txt file and try again from another folder, "
19 "e.g.:\n "
20 "\n rm CMakeCache.txt"
21 "\n mkdir build"
22 "\n cd build"
23 "\n cmake ..")
24 endif()
25
26 set(CMAKE_MODULE_PATH "${CMAKE_MODULE_PATH};${CMAKE_CURRENT_SOURCE_DIR}/cmake")
27
28 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin")
29 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${EXECUTABLE_OUTPUT_PATH}")
30
31 # Use solution folders.
32 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
33 set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMake Targets")
34
35 if(NOT ${CMAKE_VERSION} VERSION_LESS "3.15.0")
36 if(WIN32)
37 cmake_policy(SET CMP0091 NEW)
38 message(STATUS "Setting policy CMP0091 to NEW")
39 endif()
40 endif()
41
42 # ##############################################################################
43 #
44 # project settings
45 #
46 # ##############################################################################
47
48 project(tesseract C CXX)
49
50 # Get version with components from VERSION file.
51 file(STRINGS "VERSION" VERSION_PLAIN)
52 string(REGEX REPLACE "^([^.]*)\\..*" "\\1" VERSION_MAJOR ${VERSION_PLAIN})
53 string(REGEX REPLACE "^[^.]*\\.([^.]*)\\..*" "\\1" VERSION_MINOR
54 ${VERSION_PLAIN})
55 string(REGEX REPLACE "^[^.]*\\.[^.]*\\.([0-9]*).*" "\\1" VERSION_PATCH
56 ${VERSION_PLAIN})
57 if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/.git)
58 execute_process(COMMAND git --git-dir ${CMAKE_CURRENT_SOURCE_DIR}/.git
59 describe --abbrev=4 OUTPUT_VARIABLE GIT_REV)
60 string(REGEX REPLACE "\n$" "" PACKAGE_VERSION "${GIT_REV}")
61 endif()
62 if(NOT PACKAGE_VERSION)
63 set(PACKAGE_VERSION ${VERSION_PLAIN})
64 endif()
65
66 # Provide also same macro names as autoconf (see configure.ac).
67 set(GENERIC_MAJOR_VERSION ${VERSION_MAJOR})
68 set(GENERIC_MINOR_VERSION ${VERSION_MINOR})
69 set(GENERIC_MICRO_VERSION ${VERSION_PATCH})
70
71 set(MINIMUM_LEPTONICA_VERSION 1.74)
72
73 # ##############################################################################
74 #
75 # options
76 #
77 # ##############################################################################
78
79 message(STATUS "Configuring tesseract version ${PACKAGE_VERSION}...")
80
81 if(WIN32)
82 option(SW_BUILD "Build with sw" ON)
83 else()
84 option(SW_BUILD "Build with sw" OFF)
85 endif()
86 option(OPENMP_BUILD "Build with openmp support" OFF) # see issue #1662
87 option(GRAPHICS_DISABLED "Disable disable graphics (ScrollView)" OFF)
88 option(DISABLED_LEGACY_ENGINE "Disable the legacy OCR engine" OFF)
89 option(ENABLE_LTO "Enable link-time optimization" OFF)
90 option(FAST_FLOAT "Enable float for LSTM" ON)
91 option(ENABLE_NATIVE
92 "Enable optimization for host CPU (could break HW compatibility)" OFF)
93 # see
94 # https://stackoverflow.com/questions/52653025/why-is-march-native-used-so-rarely
95 option(BUILD_TRAINING_TOOLS "Build training tools" ON)
96 option(BUILD_TESTS "Build tests" OFF)
97 option(USE_SYSTEM_ICU "Use system ICU" OFF)
98 option(DISABLE_TIFF "Disable build with libtiff (if available)" OFF)
99 option(DISABLE_ARCHIVE "Disable build with libarchive (if available)" OFF)
100 option(DISABLE_CURL "Disable build with libcurl (if available)" OFF)
101 option(INSTALL_CONFIGS "Install tesseract configs" ON)
102
103 if(NOT ${CMAKE_VERSION} VERSION_LESS "3.15.0")
104 if(WIN32 AND MSVC)
105 option(WIN32_MT_BUILD "Build with MT flag for MSVC" OFF)
106 endif()
107 endif()
108
109 # ##############################################################################
110 #
111 # compiler and linker
112 #
113 # ##############################################################################
114
115 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
116 set(CLANG 1)
117 endif()
118
119 if(NOT CMAKE_BUILD_TYPE)
120 message(STATUS "Setting build type to 'Release' as none was specified.")
121 set(CMAKE_BUILD_TYPE
122 Release
123 CACHE STRING "Choose the type of build." FORCE)
124 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release")
125 endif()
126
127 include(CheckCXXCompilerFlag)
128
129 set(CMAKE_CXX_STANDARD 17)
130 if("cxx_std_20" IN_LIST CMAKE_CXX_COMPILE_FEATURES)
131 set(CMAKE_CXX_STANDARD 20)
132 endif()
133 set(CMAKE_CXX_STANDARD_REQUIRED ON)
134 if(NOT CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
135 # cygwin gnu c++ needs to use -std=gnu++17 instead of -std=c++17
136 set(CMAKE_CXX_EXTENSIONS OFF)
137 endif()
138
139 if(BUILD_SHARED_LIBS)
140 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
141 endif()
142
143 # LTO
144 cmake_policy(SET CMP0069 NEW)
145 include(CheckIPOSupported)
146 check_ipo_supported(RESULT LTO_SUPPORTED OUTPUT error)
147 if(LTO_SUPPORTED)
148 message(STATUS "IPO / LTO supported")
149 else()
150 message(STATUS "IPO / LTO not supported: <${error}>")
151 endif()
152
153 set(MARCH_NATIVE_OPT OFF)
154 if(ENABLE_NATIVE)
155 check_cxx_compiler_flag("-march=native" COMPILER_SUPPORTS_MARCH_NATIVE)
156 if(COMPILER_SUPPORTS_MARCH_NATIVE)
157 set(DOTPRODUCT_FLAGS "${DOTPRODUCT_FLAGS} -march=native")
158 if(NOT CLANG AND MSVC)
159 # clang-cl does not know this argument
160 set(DOTPRODUCT_FLAGS "${DOTPRODUCT_FLAGS} -mtune=native")
161 endif()
162 set(MARCH_NATIVE_OPT ON)
163 endif(COMPILER_SUPPORTS_MARCH_NATIVE)
164 endif(ENABLE_NATIVE)
165
166 message(STATUS "CMAKE_SYSTEM_PROCESSOR=<${CMAKE_SYSTEM_PROCESSOR}>")
167
168 if(CMAKE_SYSTEM_PROCESSOR MATCHES "x86|x86_64|AMD64|amd64|i386|i686")
169
170 set(HAVE_NEON FALSE)
171 if(MSVC)
172 set(HAVE_AVX ON)
173 set(AVX_COMPILE_FLAGS "/arch:AVX")
174 add_definitions("-DHAVE_AVX")
175
176 set(HAVE_AVX2 ON)
177 set(AVX2_COMPILE_FLAGS "/arch:AVX2")
178 add_definitions("-DHAVE_AVX2")
179
180 set(HAVE_AVX512F ON)
181 set(AVX512F_COMPILE_FLAGS "/arch:AVX512")
182 add_definitions("-DHAVE_AVX512F")
183
184 set(HAVE_FMA ON)
185 set(FMA_COMPILE_FLAGS "-D__FMA__")
186 add_definitions("-DHAVE_FMA")
187
188 set(HAVE_SSE4_1 ON)
189 set(SSE4_1_COMPILE_FLAGS "-D__SSE4_1__")
190 add_definitions("-DHAVE_SSE4_1")
191
192 set(DOTPRODUCT_FLAGS "${DOTPRODUCT_FLAGS} -openmp:experimental")
193 add_definitions("-DOPENMP_SIMD")
194
195 # clang with MSVC compatibility
196 if(CLANG)
197 set(CMAKE_CXX_FLAGS
198 "${CMAKE_CXX_FLAGS} -Wno-microsoft-unqualified-friend")
199 if(HAVE_FMA)
200 set(FMA_COMPILE_FLAGS "-mfma ${FMA_COMPILE_FLAGS}")
201 endif(HAVE_FMA)
202 if(HAVE_SSE4_1)
203 set(SSE4_1_COMPILE_FLAGS "-msse4.1 ${SSE4_1_COMPILE_FLAGS}")
204 endif(HAVE_SSE4_1)
205 endif(CLANG)
206 else() # if not MSVC
207 check_cxx_compiler_flag("-mavx" HAVE_AVX)
208 if(HAVE_AVX)
209 set(AVX_COMPILE_FLAGS "-mavx")
210 add_definitions("-DHAVE_AVX")
211 endif(HAVE_AVX)
212
213 check_cxx_compiler_flag("-mavx2" HAVE_AVX2)
214 if(HAVE_AVX2)
215 set(AVX2_COMPILE_FLAGS "-mavx2")
216 add_definitions("-DHAVE_AVX2")
217 endif()
218
219 check_cxx_compiler_flag("-mavx512f" HAVE_AVX512F)
220 if(HAVE_AVX512F)
221 set(AVX512F_COMPILE_FLAGS "-mavx512f")
222 add_definitions("-DHAVE_AVX512F")
223 endif()
224
225 check_cxx_compiler_flag("-mfma" HAVE_FMA)
226 if(HAVE_FMA)
227 set(FMA_COMPILE_FLAGS "-mfma")
228 add_definitions("-DHAVE_FMA")
229 endif()
230
231 check_cxx_compiler_flag("-msse4.1" HAVE_SSE4_1)
232 if(HAVE_SSE4_1)
233 set(SSE4_1_COMPILE_FLAGS "-msse4.1")
234 add_definitions("-DHAVE_SSE4_1")
235 endif()
236
237 check_cxx_compiler_flag("-fopenmp-simd" OPENMP_SIMD)
238 if(OPENMP_SIMD)
239 set(DOTPRODUCT_FLAGS "${DOTPRODUCT_FLAGS} -fopenmp-simd")
240 add_definitions("-DOPENMP_SIMD")
241 endif(OPENMP_SIMD)
242 endif(MSVC)
243
244 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "arm64|aarch64.*|AARCH64.*")
245
246 set(HAVE_AVX FALSE)
247 set(HAVE_AVX2 FALSE)
248 set(HAVE_AVX512F FALSE)
249 set(HAVE_FMA FALSE)
250 set(HAVE_SSE4_1 FALSE)
251 set(HAVE_NEON TRUE)
252
253 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "arm.*")
254
255 set(HAVE_AVX FALSE)
256 set(HAVE_AVX2 FALSE)
257 set(HAVE_AVX512F FALSE)
258 set(HAVE_FMA FALSE)
259 set(HAVE_SSE4_1 FALSE)
260
261 check_cxx_compiler_flag("-mfpu=neon" HAVE_NEON)
262 if(HAVE_NEON)
263 set(NEON_COMPILE_FLAGS "-mfpu=neon")
264 endif(HAVE_NEON)
265
266 else()
267
268 set(HAVE_AVX FALSE)
269 set(HAVE_AVX2 FALSE)
270 set(HAVE_AVX512F FALSE)
271 set(HAVE_FMA FALSE)
272 set(HAVE_NEON FALSE)
273 set(HAVE_SSE4_1 FALSE)
274
275 endif(CMAKE_SYSTEM_PROCESSOR MATCHES "x86|x86_64|AMD64|amd64|i386|i686")
276
277 if(HAVE_NEON)
278 message(STATUS "LTO build is not supported on arm/RBPi.")
279 set(ENABLE_LTO FALSE) # enable LTO cause fatal error on arm/RBPi
280 endif()
281
282 # Compiler specific environment
283 if(CMAKE_COMPILER_IS_GNUCXX OR MINGW)
284 set(CMAKE_CXX_FLAGS_DEBUG
285 "${CMAKE_CXX_FLAGS_DEBUG} -Wall -DDEBUG -pedantic -Og")
286 elseif(MSVC)
287 add_definitions(-D_CRT_SECURE_NO_WARNINGS)
288 add_definitions(-D_CRT_NONSTDC_NO_DEPRECATE) # strdup
289 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /utf-8")
290 if(NOT CLANG)
291 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
292 endif()
293 # Hide some warnings for release target wd4244 'argument': conversion from
294 # 'uint64_t' to 'unsigned int', possible loss of data wd4251 needs to have
295 # dll-interface wd4267 return': conversion from 'size_t' to 'int', possible
296 # loss of data wd4275 non dll-interface class wd4305 ...truncation from
297 # 'double' to 'float'
298 set(CMAKE_CXX_FLAGS_RELEASE
299 "${CMAKE_CXX_FLAGS_RELEASE} /wd4244 /wd4305 /wd4267 /wd4251 /wd4275 /wd4005"
300 )
301 set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /wd4068")
302 # Don't use /Wall because it generates too many warnings.
303 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /W0 /bigobj")
304 # MT flag
305 if(WIN32_MT_BUILD)
306 set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")
307 message(STATUS "Building with static CRT.")
308 endif()
309 endif()
310 if(CLANG) # clang all platforms
311 set(CMAKE_CXX_FLAGS_RELEASE
312 "${CMAKE_CXX_FLAGS_RELEASE} -Wno-unused-command-line-argument")
313 set(CMAKE_CXX_FLAGS_DEBUG
314 "${CMAKE_CXX_FLAGS_DEBUG} -Wall -DDEBUG -pedantic -O0")
315 endif()
316
317 if(OPENMP_BUILD
318 AND MSVC
319 AND "${MSVC_VERSION}" LESS 1929)
320 set(OPENMP_BUILD OFF)
321 endif()
322 if(OPENMP_BUILD)
323 find_package(OpenMP QUIET)
324 # https://stackoverflow.com/questions/12399422
325 # how-to-set-linker-flags-for-openmp-in-cmakes-try-compile-function
326 if(NOT OpenMP_FOUND
327 AND CLANG
328 AND WIN32)
329 # workaround because find_package(OpenMP) does not work for clang-cl
330 # https://gitlab.kitware.com/cmake/cmake/issues/19404
331 check_include_file_cxx(omp.h HAVE_OMP_H_INCLUDE)
332 find_library(OpenMP_LIBRARY NAMES omp libomp.lib)
333 message(">> OpenMP_LIBRARY: ${OpenMP_LIBRARY}")
334 if(MSVC)
335 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /openmp")
336 else()
337 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fopenmp")
338 endif()
339 set(OpenMP_FOUND 1)
340 # OpenMP 3.1 is fully supported from Clang 3.8.0
341 add_definitions(-D_OPENMP=201107)
342 endif()
343 if(MSVC)
344 # Note: -openmp:llvm is available for X64 from MSVC 16.9 from MSVC 16.10
345 # Preview 2 there is support also for x86 and arm64
346 # https://devblogs.microsoft.com/cppblog/openmp-updates-and-fixes-for-cpp-in-visual-studio-2019-16-10/
347 if("${OpenMP_CXX_FLAGS}" STREQUAL "-openmp")
348 set(OpenMP_CXX_FLAGS "-openmp:llvm")
349 endif()
350 endif()
351 if(OpenMP_FOUND)
352 message(">> OpenMP_FOUND ${OpenMP_FOUND} version: ${OpenMP_CXX_VERSION}")
353 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${OpenMP_CXX_FLAGS}")
354 if(NOT TARGET OpenMP::OpenMP_CXX)
355 add_library(OpenMP::OpenMP_CXX IMPORTED INTERFACE)
356 endif()
357 endif()
358 endif()
359
360 if(CYGWIN)
361 add_definitions(-D__CYGWIN__)
362 elseif(UNIX)
363 if(NOT ANDROID)
364 set(LIB_pthread pthread)
365 endif()
366 elseif(WIN32)
367 set(LIB_Ws2_32 Ws2_32)
368 endif()
369
370 add_definitions("-DCMAKE_BUILD")
371
372 # ##############################################################################
373 #
374 # packages
375 #
376 # ##############################################################################
377 include(CheckFunctions)
378
379 if(SW_BUILD)
380 find_package(SW REQUIRED)
381 if(BUILD_SHARED_LIBS)
382 set(SW_BUILD_SHARED_LIBS 1)
383 else()
384 set(SW_BUILD_SHARED_LIBS 0)
385 endif()
386 sw_add_package(org.sw.demo.danbloomberg.leptonica
387 org.sw.demo.libarchive.libarchive)
388 if(BUILD_TRAINING_TOOLS)
389 sw_add_package(org.sw.demo.gnome.pango.pangocairo
390 org.sw.demo.unicode.icu.i18n)
391 endif()
392 sw_execute()
393 else()
394 find_package(PkgConfig)
395 # Check for required library. option -DLeptonica_DIR=path => cmake hint where
396 # to find leptonica
397 find_package(Leptonica ${MINIMUM_LEPTONICA_VERSION} CONFIG)
398 if(NOT Leptonica_FOUND AND PKG_CONFIG_EXECUTABLE)
399 pkg_check_modules(Leptonica lept>=${MINIMUM_LEPTONICA_VERSION})
400 link_directories(${Leptonica_LIBRARY_DIRS})
401 endif()
402 if(NOT Leptonica_FOUND)
403 message(FATAL_ERROR "Cannot find required library Leptonica. Quitting!")
404 else()
405 message(STATUS "Found leptonica version: ${Leptonica_VERSION}")
406 endif(NOT Leptonica_FOUND)
407 include_directories(${Leptonica_INCLUDE_DIRS})
408
409 check_leptonica_tiff_support()
410 if ((NOT LEPT_TIFF_RESULT EQUAL 0) AND LEPT_TIFF_COMPILE_SUCCESS)
411 message(NOTICE "Leptonica was build without TIFF support! Disabling TIFF support...")
412 set(DISABLE_TIFF ON)
413 elseif(NOT ${CMAKE_VERSION} VERSION_LESS "3.25")
414 message(STATUS "Leptonica was build with TIFF support.")
415 endif()
416
417 # Check for optional libraries.
418 if(DISABLE_TIFF)
419 set(HAVE_TIFFIO_H OFF)
420 message(STATUS "TIFF support disabled.")
421 else(DISABLE_TIFF)
422 find_package(TIFF) # for tesseract
423 if(NOT TIFF_FOUND AND PKG_CONFIG_EXECUTABLE)
424 # try PKG_CONFIG to find libtiff if cmake failed
425 pkg_check_modules(TIFF libtiff-4)
426 endif()
427 if(TIFF_FOUND)
428 set(HAVE_TIFFIO_H ON)
429 include_directories(${TIFF_INCLUDE_DIRS})
430 endif(TIFF_FOUND)
431 endif(DISABLE_TIFF)
432 if(DISABLE_ARCHIVE)
433 set(HAVE_LIBARCHIVE OFF)
434 message(STATUS "LibArchive support disabled.")
435 else(DISABLE_ARCHIVE)
436 find_package(LibArchive)
437 if(NOT LibArchive_FOUND AND PKG_CONFIG_EXECUTABLE)
438 # try PKG_CONFIG to find libarchive if cmake failed
439 pkg_check_modules(LibArchive libarchive)
440 endif()
441 if(LibArchive_FOUND)
442 set(HAVE_LIBARCHIVE ON)
443 include_directories(${LibArchive_INCLUDE_DIRS})
444 endif(LibArchive_FOUND)
445 endif(DISABLE_ARCHIVE)
446 if(DISABLE_CURL)
447 set(HAVE_LIBCURL OFF)
448 message(STATUS "CURL support disabled.")
449 else(DISABLE_CURL)
450 find_package(CURL)
451 if(NOT CURL_FOUND AND PKG_CONFIG_EXECUTABLE)
452 # try PKG_CONFIG to find libcurl if cmake failed
453 pkg_check_modules(CURL libcurl)
454 endif()
455 if(CURL_FOUND)
456 set(HAVE_LIBCURL ON)
457 include_directories(${CURL_INCLUDE_DIRS})
458 endif(CURL_FOUND)
459 endif(DISABLE_CURL)
460 endif()
461
462 # ##############################################################################
463 #
464 # configure
465 #
466 # ##############################################################################
467
468 if(MSVC)
469 set(DOTPRODUCT_FLAGS "${DOTPRODUCT_FLAGS} /fp:fast")
470 else()
471 set(DOTPRODUCT_FLAGS "${DOTPRODUCT_FLAGS} -O3 -ffast-math")
472 endif()
473
474 include (GNUInstallDirs)
475
476 set(AUTOCONFIG_SRC ${CMAKE_CURRENT_BINARY_DIR}/config_auto.h.in)
477 set(AUTOCONFIG ${CMAKE_CURRENT_BINARY_DIR}/config_auto.h)
478 add_definitions(-DHAVE_CONFIG_H)
479
480 if(GRAPHICS_DISABLED)
481 message("ScrollView debugging disabled.")
482 endif()
483 set(CMAKE_REQUIRED_INCLUDES
484 ${CMAKE_REQUIRED_INCLUDES} "${CMAKE_PREFIX_PATH}/include"
485 ${CMAKE_INSTALL_INCLUDEDIR})
486 include(Configure)
487
488 configure_file(${AUTOCONFIG_SRC} ${AUTOCONFIG} @ONLY)
489
490 set(INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR})
491 set(LIBRARY_DIRS ${CMAKE_INSTALL_LIBDIR})
492
493 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/include/tesseract/version.h.in
494 ${CMAKE_CURRENT_BINARY_DIR}/include/tesseract/version.h @ONLY)
495
496 include(CMakePackageConfigHelpers)
497 include(GenerateExportHeader)
498
499 # show summary of configuration
500 if(${CMAKE_BUILD_TYPE} MATCHES Debug)
501 set(COMPILER_FLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG}")
502 elseif(${CMAKE_BUILD_TYPE} MATCHES Release)
503 set(COMPILER_FLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE}")
504 if(LTO_SUPPORTED AND ENABLE_LTO)
505 set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
506 else()
507 set(CMAKE_INTERPROCEDURAL_OPTIMIZATION FALSE)
508 endif() # LTO_SUPPORTED
509 endif()
510
511 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
512 set(BUILD_ARCH "64 bits")
513 elseif(CMAKE_SIZEOF_VOID_P EQUAL 4)
514 set(BUILD_ARCH "32 bits")
515 endif()
516
517 message(STATUS)
518 message(STATUS "General configuration for Tesseract ${PACKAGE_VERSION}")
519 message(STATUS "--------------------------------------------------------")
520 message(STATUS "Build type: ${CMAKE_BUILD_TYPE} ${BUILD_ARCH}")
521 message(STATUS "Compiler: ${CMAKE_CXX_COMPILER_ID}")
522 message(STATUS "Used standard: C++${CMAKE_CXX_STANDARD}")
523 message(STATUS "CXX compiler options: ${COMPILER_FLAGS}")
524 get_directory_property(DirCompDefs COMPILE_DEFINITIONS)
525 message(STATUS "Compile definitions = ${DirCompDefs}")
526 message(STATUS "Linker options: ${CMAKE_EXE_LINKER_FLAGS} "
527 "${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UP}}")
528 message(STATUS "Install directory: ${CMAKE_INSTALL_PREFIX}")
529 message(STATUS "HAVE_AVX: ${HAVE_AVX}")
530 message(STATUS "HAVE_AVX2: ${HAVE_AVX2}")
531 message(STATUS "HAVE_AVX512F: ${HAVE_AVX512F}")
532 message(STATUS "HAVE_FMA: ${HAVE_FMA}")
533 message(STATUS "HAVE_SSE4_1: ${HAVE_SSE4_1}")
534 message(STATUS "MARCH_NATIVE_OPT: ${MARCH_NATIVE_OPT}")
535 message(STATUS "HAVE_NEON: ${HAVE_NEON}")
536 message(STATUS "Link-time optimization: ${CMAKE_INTERPROCEDURAL_OPTIMIZATION}")
537 message(STATUS "--------------------------------------------------------")
538 message(STATUS "Build with sw [SW_BUILD]: ${SW_BUILD}")
539 message(STATUS "Build with openmp support [OPENMP_BUILD]: ${OPENMP_BUILD}")
540 message(STATUS "Build with libarchive support [HAVE_LIBARCHIVE]: "
541 "${HAVE_LIBARCHIVE}")
542 message(STATUS "Build with libcurl support [HAVE_LIBCURL]: ${HAVE_LIBCURL}")
543 message(STATUS "Enable float for LSTM [FAST_FLOAT]: ${FAST_FLOAT}")
544 message(STATUS "Enable optimization for host CPU (could break HW compatibility)"
545 " [ENABLE_NATIVE]: ${ENABLE_NATIVE}")
546 message(STATUS "Disable disable graphics (ScrollView) [GRAPHICS_DISABLED]: "
547 "${GRAPHICS_DISABLED}")
548 message(STATUS "Disable the legacy OCR engine [DISABLED_LEGACY_ENGINE]: "
549 "${DISABLED_LEGACY_ENGINE}")
550 message(STATUS "Build training tools [BUILD_TRAINING_TOOLS]: "
551 "${BUILD_TRAINING_TOOLS}")
552 message(STATUS "Build tests [BUILD_TESTS]: ${BUILD_TESTS}")
553 message(STATUS "Use system ICU Library [USE_SYSTEM_ICU]: ${USE_SYSTEM_ICU}")
554 message(
555 STATUS "Install tesseract configs [INSTALL_CONFIGS]: ${INSTALL_CONFIGS}")
556 message(STATUS "--------------------------------------------------------")
557 message(STATUS)
558
559 # ##############################################################################
560 #
561 # build
562 #
563 # ##############################################################################
564
565 include(BuildFunctions)
566 include(SourceGroups)
567
568 add_definitions(-D_SILENCE_STDEXT_HASH_DEPRECATION_WARNINGS=1)
569
570 include_directories(${CMAKE_CURRENT_BINARY_DIR})
571 include_directories(${CMAKE_CURRENT_BINARY_DIR}/include)
572 if(ANDROID_TOOLCHAIN)
573 include_directories(${ANDROID_TOOLCHAIN}/sysroot/usr/include)
574 add_compile_definitions(__ANDROID_API_FUTURE__)
575 endif()
576
577 # ##############################################################################
578 # LIBRARY tesseract
579 # ##############################################################################
580
581 file(
582 GLOB
583 TESSERACT_SRC
584 src/ccmain/*.cpp
585 src/ccstruct/*.cpp
586 src/ccutil/*.cpp
587 src/classify/*.cpp
588 src/cutil/*.cpp
589 src/dict/*.cpp
590 src/lstm/*.cpp
591 src/textord/*.cpp
592 src/viewer/*.cpp
593 src/wordrec/*.cpp)
594
595 if(DISABLED_LEGACY_ENGINE)
596 # prepend path to list of source files
597 function(prepend_path srcs path)
598 set(tmp, "")
599 foreach(src IN LISTS ${srcs})
600 list(APPEND tmp ${path}/${src})
601 endforeach(src ${srcs})
602 set(${srcs}
603 ${tmp}
604 PARENT_SCOPE)
605 endfunction()
606
607 set(TESSERACT_SRC_LEGACY
608 src/ccmain/adaptions.cpp
609 src/ccmain/docqual.cpp
610 src/ccmain/equationdetect.cpp
611 src/ccmain/fixspace.cpp
612 src/ccmain/fixxht.cpp
613 src/ccmain/osdetect.cpp
614 src/ccmain/par_control.cpp
615 src/ccmain/recogtraining.cpp
616 src/ccmain/superscript.cpp
617 src/ccmain/tessbox.cpp
618 src/ccmain/tfacepp.cpp
619 src/ccstruct/fontinfo.cpp
620 src/ccstruct/params_training_featdef.cpp
621 src/ccutil/ambigs.cpp
622 src/ccutil/bitvector.cpp
623 src/ccutil/indexmapbidi.cpp
624 src/classify/adaptive.cpp
625 src/classify/adaptmatch.cpp
626 src/classify/blobclass.cpp
627 src/classify/cluster.cpp
628 src/classify/clusttool.cpp
629 src/classify/cutoffs.cpp
630 src/classify/featdefs.cpp
631 src/classify/float2int.cpp
632 src/classify/fpoint.cpp
633 src/classify/intfeaturespace.cpp
634 src/classify/intfx.cpp
635 src/classify/intmatcher.cpp
636 src/classify/intproto.cpp
637 src/classify/kdtree.cpp
638 src/classify/mf.cpp
639 src/classify/mfoutline.cpp
640 src/classify/mfx.cpp
641 src/classify/normfeat.cpp
642 src/classify/normmatch.cpp
643 src/classify/ocrfeatures.cpp
644 src/classify/outfeat.cpp
645 src/classify/picofeat.cpp
646 src/classify/protos.cpp
647 src/classify/shapeclassifier.cpp
648 src/classify/shapetable.cpp
649 src/classify/tessclassifier.cpp
650 src/classify/trainingsample.cpp
651 src/dict/permdawg.cpp
652 src/dict/hyphen.cpp
653 src/wordrec/associate.cpp
654 src/wordrec/chop.cpp
655 src/wordrec/chopper.cpp
656 src/wordrec/drawfx.cpp
657 src/wordrec/findseam.cpp
658 src/wordrec/gradechop.cpp
659 src/wordrec/language_model.cpp
660 src/wordrec/lm_consistency.cpp
661 src/wordrec/lm_pain_points.cpp
662 src/wordrec/lm_state.cpp
663 src/wordrec/outlines.cpp
664 src/wordrec/params_model.cpp
665 src/wordrec/pieces.cpp
666 src/wordrec/plotedges.cpp
667 src/wordrec/render.cpp
668 src/wordrec/segsearch.cpp
669 src/wordrec/wordclass.cpp)
670 prepend_path(TESSERACT_SRC_LEGACY "${CMAKE_CURRENT_SOURCE_DIR}")
671 list(REMOVE_ITEM TESSERACT_SRC ${TESSERACT_SRC_LEGACY})
672 endif(DISABLED_LEGACY_ENGINE)
673
674 list(APPEND arch_files src/arch/dotproduct.cpp src/arch/simddetect.cpp
675 src/arch/intsimdmatrix.cpp)
676
677 if(DOTPRODUCT_FLAGS)
678 set_source_files_properties(src/arch/dotproduct.cpp
679 PROPERTIES COMPILE_FLAGS ${DOTPRODUCT_FLAGS})
680 endif(DOTPRODUCT_FLAGS)
681 if(HAVE_AVX)
682 list(APPEND arch_files_opt src/arch/dotproductavx.cpp)
683 set_source_files_properties(src/arch/dotproductavx.cpp
684 PROPERTIES COMPILE_FLAGS ${AVX_COMPILE_FLAGS})
685 endif(HAVE_AVX)
686 if(HAVE_AVX2)
687 list(APPEND arch_files_opt src/arch/intsimdmatrixavx2.cpp
688 src/arch/dotproductavx.cpp)
689 set_source_files_properties(src/arch/intsimdmatrixavx2.cpp
690 PROPERTIES COMPILE_FLAGS ${AVX2_COMPILE_FLAGS})
691 endif(HAVE_AVX2)
692 if(HAVE_AVX512F)
693 list(APPEND arch_files_opt src/arch/dotproductavx512.cpp)
694 set_source_files_properties(src/arch/dotproductavx512.cpp
695 PROPERTIES COMPILE_FLAGS ${AVX512F_COMPILE_FLAGS})
696 endif(HAVE_AVX512F)
697 if(HAVE_FMA)
698 list(APPEND arch_files_opt src/arch/dotproductfma.cpp)
699 set_source_files_properties(src/arch/dotproductfma.cpp
700 PROPERTIES COMPILE_FLAGS ${FMA_COMPILE_FLAGS})
701 endif(HAVE_FMA)
702 if(HAVE_SSE4_1)
703 list(APPEND arch_files_opt src/arch/dotproductsse.cpp
704 src/arch/intsimdmatrixsse.cpp)
705 set_source_files_properties(
706 src/arch/dotproductsse.cpp src/arch/intsimdmatrixsse.cpp
707 PROPERTIES COMPILE_FLAGS ${SSE4_1_COMPILE_FLAGS})
708 endif(HAVE_SSE4_1)
709 if(HAVE_NEON)
710 list(APPEND arch_files_opt src/arch/dotproductneon.cpp
711 src/arch/intsimdmatrixneon.cpp)
712 if(NEON_COMPILE_FLAGS)
713 set_source_files_properties(
714 src/arch/dotproductneon.cpp src/arch/intsimdmatrixneon.cpp
715 PROPERTIES COMPILE_FLAGS ${NEON_COMPILE_FLAGS})
716 endif()
717 endif(HAVE_NEON)
718
719 file(
720 GLOB_RECURSE
721 TESSERACT_HDR
722 include/*
723 src/arch/*.h
724 src/ccmain/*.h
725 src/ccstruct/*.h
726 src/ccutil/*.h
727 src/classify/*.h
728 src/cutil/*.h
729 src/dict/*.h
730 src/lstm/*.h
731 src/textord/*.h
732 src/viewer/*.h
733 src/wordrec/*.h)
734
735 set(TESSERACT_SRC
736 ${TESSERACT_SRC}
737 src/api/baseapi.cpp
738 src/api/capi.cpp
739 src/api/renderer.cpp
740 src/api/altorenderer.cpp
741 src/api/pagerenderer.cpp
742 src/api/hocrrenderer.cpp
743 src/api/lstmboxrenderer.cpp
744 src/api/pdfrenderer.cpp
745 src/api/wordstrboxrenderer.cpp)
746
747 set(TESSERACT_CONFIGS
748 tessdata/configs/alto
749 tessdata/configs/ambigs.train
750 tessdata/configs/api_config
751 tessdata/configs/bazaar
752 tessdata/configs/bigram
753 tessdata/configs/box.train
754 tessdata/configs/box.train.stderr
755 tessdata/configs/digits
756 tessdata/configs/get.images
757 tessdata/configs/hocr
758 tessdata/configs/inter
759 tessdata/configs/kannada
760 tessdata/configs/linebox
761 tessdata/configs/logfile
762 tessdata/configs/lstm.train
763 tessdata/configs/lstmbox
764 tessdata/configs/lstmdebug
765 tessdata/configs/makebox
766 tessdata/configs/page
767 tessdata/configs/pdf
768 tessdata/configs/quiet
769 tessdata/configs/rebox
770 tessdata/configs/strokewidth
771 tessdata/configs/tsv
772 tessdata/configs/txt
773 tessdata/configs/unlv
774 tessdata/configs/wordstrbox)
775
776 set(TESSERACT_TESSCONFIGS
777 tessdata/tessconfigs/batch tessdata/tessconfigs/batch.nochop
778 tessdata/tessconfigs/matdemo tessdata/tessconfigs/msdemo
779 tessdata/tessconfigs/nobatch tessdata/tessconfigs/segdemo)
780
781 set(LIBTESSFILES ${TESSERACT_SRC} ${arch_files} ${arch_files_opt}
782 ${TESSERACT_HDR})
783
784 source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR} FILES ${LIBTESSFILES})
785
786 add_library(libtesseract ${LIBTESSFILES})
787 target_include_directories(
788 libtesseract BEFORE
789 PRIVATE src
790 PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
791 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/arch>
792 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/ccmain>
793 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/ccstruct>
794 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/ccutil>
795 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/classify>
796 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/cutil>
797 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/dict>
798 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/lstm>
799 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/textord>
800 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/viewer>
801 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/wordrec>
802 $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/training>)
803 if(BUILD_SHARED_LIBS)
804 target_compile_definitions(
805 libtesseract
806 PRIVATE -DTESS_EXPORTS
807 INTERFACE -DTESS_IMPORTS)
808 # generate_export_header (libtesseract EXPORT_MACRO_NAME TESS_API)
809 endif()
810 target_link_libraries(libtesseract PRIVATE ${LIB_Ws2_32} ${LIB_pthread})
811 if(OpenMP_CXX_FOUND)
812 target_link_libraries(libtesseract PUBLIC OpenMP::OpenMP_CXX)
813 endif()
814 if(LibArchive_FOUND)
815 target_link_libraries(libtesseract PUBLIC ${LibArchive_LIBRARIES})
816 endif(LibArchive_FOUND)
817 if(CURL_FOUND)
818 if(NOT CURL_LIBRARIES)
819 target_link_libraries(libtesseract PUBLIC CURL::libcurl)
820 else()
821 target_link_libraries(libtesseract PUBLIC ${CURL_LIBRARIES})
822 endif()
823 endif(CURL_FOUND)
824
825 set_target_properties(
826 libtesseract PROPERTIES VERSION
827 ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH})
828 set_target_properties(
829 libtesseract PROPERTIES SOVERSION
830 ${VERSION_MAJOR}.${VERSION_MINOR})
831
832 set_target_properties(
833 libtesseract
834 PROPERTIES
835 OUTPUT_NAME
836 tesseract$<$<BOOL:${WIN32}>:${VERSION_MAJOR}${VERSION_MINOR}$<$<CONFIG:DEBUG>:d>>
837 )
838
839 if(SW_BUILD)
840 target_link_libraries(libtesseract PUBLIC org.sw.demo.danbloomberg.leptonica
841 org.sw.demo.libarchive.libarchive)
842 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/TesseractTargets.cmake
843 "include(${CMAKE_CURRENT_BINARY_DIR}/cppan.cmake)\n")
844 export(
845 TARGETS libtesseract
846 APPEND
847 FILE ${CMAKE_CURRENT_BINARY_DIR}/TesseractTargets.cmake
848 NAMESPACE Tesseract::)
849 else()
850 target_link_libraries(libtesseract PUBLIC ${Leptonica_LIBRARIES})
851 export(
852 TARGETS libtesseract
853 FILE ${CMAKE_CURRENT_BINARY_DIR}/TesseractTargets.cmake
854 NAMESPACE Tesseract::)
855 endif()
856
857 if(WIN32
858 AND CLANG
859 AND OPENMP_BUILD)
860 # Workaround for "libomp.lib is not automatically added on Windows" see:
861 # http://lists.llvm.org/pipermail/openmp-dev/2015-August/000857.html
862 target_link_libraries(libtesseract PRIVATE ${OpenMP_LIBRARY})
863 endif()
864
865 if(ANDROID)
866 add_definitions(-DANDROID)
867 find_package(CpuFeaturesNdkCompat REQUIRED)
868 target_include_directories(
869 libtesseract
870 PRIVATE "${CpuFeaturesNdkCompat_DIR}/../../../include/ndk_compat")
871 target_link_libraries(libtesseract PRIVATE CpuFeatures::ndk_compat)
872 endif()
873
874 # ##############################################################################
875 # EXECUTABLE tesseract
876 # ##############################################################################
877
878 add_executable(tesseract src/tesseract.cpp)
879 target_link_libraries(tesseract libtesseract)
880 if(HAVE_TIFFIO_H AND WIN32)
881 target_link_libraries(tesseract ${TIFF_LIBRARIES})
882 endif()
883
884 if(OPENMP_BUILD AND UNIX)
885 target_link_libraries(tesseract pthread)
886 endif()
887
888 # ##############################################################################
889
890 if(BUILD_TESTS
891 AND EXISTS
892 ${CMAKE_CURRENT_SOURCE_DIR}/unittest/third_party/googletest/CMakeLists.txt
893 )
894 add_subdirectory(unittest/third_party/googletest)
895 endif()
896
897 if(BUILD_TRAINING_TOOLS)
898 add_subdirectory(src/training)
899 endif()
900
901 get_target_property(tesseract_NAME libtesseract NAME)
902 get_target_property(tesseract_VERSION libtesseract VERSION)
903 get_target_property(tesseract_OUTPUT_NAME libtesseract OUTPUT_NAME)
904
905 configure_file(tesseract.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/tesseract.pc.in
906 @ONLY)
907 # to resolve generator expression in OUTPUT_NAME
908 file(
909 GENERATE
910 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/tesseract_$<CONFIG>.pc
911 INPUT ${CMAKE_CURRENT_BINARY_DIR}/tesseract.pc.in)
912
913 configure_package_config_file(
914 cmake/templates/TesseractConfig.cmake.in
915 ${CMAKE_CURRENT_BINARY_DIR}/cmake/tesseract/TesseractConfig.cmake
916 INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/tesseract
917 PATH_VARS INCLUDE_DIR LIBRARY_DIRS)
918 write_basic_package_version_file(
919 ${CMAKE_CURRENT_BINARY_DIR}/cmake/tesseract/TesseractConfigVersion.cmake
920 VERSION ${PACKAGE_VERSION}
921 COMPATIBILITY SameMajorVersion)
922
923 install(
924 FILES ${CMAKE_CURRENT_BINARY_DIR}/tesseract_$<CONFIG>.pc
925 DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig
926 RENAME tesseract.pc)
927 install(TARGETS tesseract DESTINATION bin)
928 if (MSVC)
929 install(FILES $<TARGET_PDB_FILE:${PROJECT_NAME}> DESTINATION bin OPTIONAL)
930 endif()
931 install(
932 TARGETS libtesseract
933 EXPORT TesseractTargets
934 RUNTIME DESTINATION bin
935 RUNTIME DESTINATION bin
936 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
937 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
938 if (MSVC AND BUILD_SHARED_LIBS)
939 install(FILES $<TARGET_PDB_FILE:libtesseract> DESTINATION bin OPTIONAL)
940 endif()
941 install(
942 EXPORT TesseractTargets
943 NAMESPACE Tesseract::
944 DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/tesseract)
945 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/cmake
946 DESTINATION ${CMAKE_INSTALL_LIBDIR})
947
948 install(
949 FILES include/tesseract/baseapi.h
950 include/tesseract/capi.h
951 include/tesseract/renderer.h
952 ${CMAKE_CURRENT_BINARY_DIR}/include/tesseract/version.h
953 include/tesseract/ltrresultiterator.h
954 include/tesseract/pageiterator.h
955 include/tesseract/resultiterator.h
956 include/tesseract/osdetect.h
957 include/tesseract/publictypes.h
958 include/tesseract/ocrclass.h
959 include/tesseract/export.h
960 include/tesseract/unichar.h
961 # ${CMAKE_CURRENT_BINARY_DIR}/src/endianness.h
962 DESTINATION include/tesseract)
963
964 if(INSTALL_CONFIGS)
965 install(FILES ${TESSERACT_CONFIGS}
966 DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/tessdata/configs)
967 install(FILES ${TESSERACT_TESSCONFIGS}
968 DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/tessdata/tessconfigs)
969 endif()
970
971 # ##############################################################################
972 # uninstall target
973 # ##############################################################################
974 if(NOT TARGET uninstall)
975 configure_file(
976 "${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/cmake_uninstall.cmake.in"
977 "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake" IMMEDIATE @ONLY)
978
979 add_custom_target(
980 uninstall
981 COMMENT "Uninstall installed files"
982 COMMAND ${CMAKE_COMMAND} -P
983 ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
984 endif()
985
986 # ##############################################################################