Mercurial > hgrepos > Python2 > PyMuPDF

comparison mupdf-source/thirdparty/leptonica/configure.ac @ 2:b50eed0cc0ef upstream

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
ADD: MuPDF v1.26.7: the MuPDF source as downloaded by a default build of PyMuPDF 1.26.4. The directory name has changed: no version number in the expanded directory now.
author Franz Glasner <fzglas.hg@dom66.de>
date Mon, 15 Sep 2025 11:43:07 +0200
parents
children
comparison
equal deleted inserted replaced
1:1d09e1dec1d9 2:b50eed0cc0ef
1 AC_PREREQ([2.69])
2 AC_INIT([leptonica], [1.85.0])
3 AC_CONFIG_AUX_DIR([config])
4 AC_CONFIG_HEADERS([config_auto.h:config/config.h.in])
5 AC_CONFIG_SRCDIR([src/adaptmap.c])
6
7 AC_CONFIG_MACRO_DIR([m4])
8 LT_INIT
9
10 AM_INIT_AUTOMAKE
11 AC_LANG(C)
12 AC_CANONICAL_HOST
13
14 # Checks for programs.
15 AC_PROG_AWK
16 AC_PROG_CC
17 AC_PROG_CPP
18 AC_PROG_INSTALL
19 AC_PROG_LN_S
20 AC_PROG_MAKE_SET
21
22 # Checks for arguments.
23 AC_ARG_WITH([zlib], AS_HELP_STRING([--without-zlib], [do not include zlib support]))
24 AC_ARG_WITH([libpng], AS_HELP_STRING([--without-libpng], [do not include libpng support]))
25 AC_ARG_WITH([jpeg], AS_HELP_STRING([--without-jpeg], [do not include jpeg support]))
26 AC_ARG_WITH([giflib], AS_HELP_STRING([--without-giflib], [do not include giflib support]))
27 AC_ARG_WITH([libtiff], AS_HELP_STRING([--without-libtiff], [do not include libtiff support]))
28 AC_ARG_WITH([libwebp], AS_HELP_STRING([--without-libwebp], [do not include libwebp support]))
29 AC_ARG_WITH([libwebpmux], AS_HELP_STRING([--without-libwebpmux], [do not include libwebpmux support]))
30 AC_ARG_WITH([libopenjpeg], AS_HELP_STRING([--without-libopenjpeg], [do not include libopenjpeg support]))
31
32 AC_ARG_ENABLE([programs], AS_HELP_STRING([--disable-programs], [do not build additional programs]))
33 AM_CONDITIONAL([ENABLE_PROGRAMS], [test "x$enable_programs" != xno])
34
35 # Checks for libraries.
36 LT_LIB_M
37
38 AS_IF([test "x$with_zlib" = xno], [
39 zlib_missing=untried
40 ], [
41 zlib_missing=
42
43 PKG_CHECK_MODULES([ZLIB], [zlib], [
44 AC_DEFINE([HAVE_LIBZ], 1, [Define to 1 if you have zlib.])
45 ], [
46 AC_CHECK_LIB([z], [deflate], [:], [zlib_missing=library])
47 AC_CHECK_HEADER([zlib.h], [:], [zlib_missing=header])
48
49 AS_IF([test "x$zlib_missing" = x], [
50 AC_DEFINE([HAVE_LIBZ], 1, [Define to 1 if you have zlib.]) AC_SUBST([ZLIB_LIBS], [-lz])
51 ], [
52 AS_IF([test "x$with_zlib" = xyes], AC_MSG_ERROR([zlib support requested but $zlib_missing not found]))
53 ])
54 ])
55 ])
56
57 AS_IF([test "x$with_libpng" = xno], [
58 libpng_missing=untried
59 ], [
60 libpng_missing=
61
62 PKG_CHECK_MODULES([LIBPNG], [libpng], [
63 AC_DEFINE([HAVE_LIBPNG], 1, [Define to 1 if you have libpng.])
64 ], [
65 AC_CHECK_LIB([png], [png_read_png], [:], [libpng_missing=library], [$LIBM $ZLIB_LIBS])
66 AC_CHECK_HEADER([png.h], [:], [libpng_missing=headers])
67
68 AS_IF([test "x$libpng_missing" = x], [
69 AC_DEFINE([HAVE_LIBPNG], 1, [Define to 1 if you have libpng.]) AC_SUBST([LIBPNG_LIBS], [-lpng])
70 ], [
71 AS_IF([test "x$with_libpng" = xyes], AC_MSG_ERROR([libpng support requested but $libpng_missing not found]))
72 ])
73 ])
74 ])
75
76 AS_IF([test "x$with_jpeg" = xno], [
77 jpeg_missing=untried
78 ], [
79 jpeg_missing=
80
81 PKG_CHECK_MODULES([JPEG], [libjpeg], [
82 AC_DEFINE([HAVE_LIBJPEG], 1, [Define to 1 if you have jpeg.])
83 ], [
84 AC_CHECK_LIB([jpeg], [jpeg_read_scanlines], [:], [jpeg_missing=library])
85 AC_CHECK_HEADER([jpeglib.h], [:], [jpeg_missing=headers])
86
87 AS_IF([test "x$jpeg_missing" = x], [
88 AC_DEFINE([HAVE_LIBJPEG], 1, [Define to 1 if you have jpeg.]) AC_SUBST([JPEG_LIBS], [-ljpeg])
89 ], [
90 AS_IF([test "x$with_jpeg" = xyes], AC_MSG_ERROR([jpeg support requested but $jpeg_missing not found]))
91 ])
92 ])
93 ])
94
95 AS_IF([test "x$with_giflib" = xno], [
96 giflib_missing=untried
97 ], [
98 giflib_missing=
99
100 AC_CHECK_LIB([gif], [DGifOpenFileHandle], [:], [giflib_missing=library])
101 AC_CHECK_HEADER([gif_lib.h], [:], [giflib_missing=header])
102
103 AS_IF([test "x$giflib_missing" = x], [
104 AC_MSG_CHECKING([giflib is at least version 5.1 (but not 5.1.2)])
105 AC_PREPROC_IFELSE([
106 AC_LANG_SOURCE([[
107 #include <gif_lib.h>
108 #if !defined GIFLIB_MAJOR || GIFLIB_MAJOR < 5 || (GIFLIB_MAJOR == 5 && GIFLIB_MINOR == 0)
109 #error giflib version too old
110 #elif GIFLIB_MAJOR == 5 && GIFLIB_MINOR == 1 && GIFLIB_RELEASE == 2
111 #error giflib 5.1.2 is broken
112 #endif
113 ]])
114 ], [
115 AC_MSG_RESULT([yes])
116 AC_DEFINE([HAVE_LIBGIF], 1, [Define to 1 if you have giflib.]) AC_SUBST([GIFLIB_LIBS], [-lgif])
117 ], [
118 AC_MSG_RESULT([no])
119 AS_IF([test "x$with_giflib" = xyes], AC_MSG_ERROR([giflib version too old or broken]))
120 giflib_missing=old
121 ])
122 ], [
123 AS_IF([test "x$with_giflib" = xyes], AC_MSG_ERROR([giflib support requested but $giflib_missing not found]))
124 ])
125 ])
126
127 AM_CONDITIONAL([HAVE_LIBGIF], [test "x$giflib_missing" = x])
128
129 AS_IF([test "x$with_libtiff" = xno], [
130 libtiff_missing=untried
131 ], [
132 libtiff_missing=
133
134 PKG_CHECK_MODULES([LIBTIFF], [libtiff-4], [
135 AC_DEFINE([HAVE_LIBTIFF], 1, [Define to 1 if you have libtiff.])
136 ], [
137 AC_CHECK_LIB([tiff], [TIFFOpen], [:], [libtiff_missing=library], [$LIBM $ZLIB_LIBS $JPEG_LIBS])
138 AC_CHECK_HEADER([tiff.h], [:], [libtiff_missing=headers])
139
140 AS_IF([test "x$libtiff_missing" = x], [
141 AC_DEFINE([HAVE_LIBTIFF], 1, [Define to 1 if you have libtiff.]) AC_SUBST([LIBTIFF_LIBS], [-ltiff])
142 ], [
143 AS_IF([test "x$with_libtiff" = xyes], AC_MSG_ERROR([libtiff support requested but $libtiff_missing not found]))
144 ])
145 ])
146 ])
147
148 AS_IF([test "x$with_libwebp" = xno], [
149 libwebp_missing=untried
150 ], [
151 libwebp_missing=
152
153 PKG_CHECK_MODULES([LIBWEBP], [libwebp], [
154 AC_DEFINE([HAVE_LIBWEBP], 1, [Define to 1 if you have libwebp.])
155 ], [
156 AC_CHECK_LIB([webp], [WebPGetInfo], [:], [libwebp_missing=library], [$LIBM])
157 AC_CHECK_HEADER([webp/encode.h], [:], [libwebp_missing=headers])
158
159 AS_IF([test "x$libwebp_missing" = x], [
160 AC_DEFINE([HAVE_LIBWEBP], 1, [Define to 1 if you have libwebp.]) AC_SUBST([LIBWEBP_LIBS], [-lwebp])
161 ], [
162 AS_IF([test "x$with_libwebp" = xyes], AC_MSG_ERROR([libwebp support requested but $libwebp_missing not found]))
163 ])
164 ])
165 ])
166
167 AM_CONDITIONAL([HAVE_LIBWEBP], [test "x$libwebp_missing" = x])
168
169 AS_IF([test "x$with_libwebpmux" = xno], [
170 libwebpmux_missing=untried
171 ], [
172 libwebpmux_missing=
173
174 PKG_CHECK_MODULES([LIBWEBPMUX], [libwebpmux >= 0.5.0], [
175 AC_DEFINE([HAVE_LIBWEBP_ANIM], 1, [Define to 1 if you have libwebpmux.])
176 ], [
177 AC_CHECK_LIB([webpmux], [WebPAnimEncoderOptionsInit], [:], [libwebpmux_missing=library], [$LIBM])
178
179 AS_IF([test "x$libwebpmux_missing" = x], [
180 AC_DEFINE([HAVE_LIBWEBP_ANIM], 1, [Define to 1 if you have libwebpmux.]) AC_SUBST([LIBWEBPMUX_LIBS], [-lwebpmux])
181 ], [
182 AS_IF([test "x$with_libwebpmux" = xyes], AC_MSG_ERROR([libwebpmux support requested but $libwebpmux_missing not found]))
183 ])
184 ])
185 ])
186
187 AM_CONDITIONAL([HAVE_LIBWEBP_ANIM], [test "x$libwebpmux_missing" = x])
188
189 AS_IF([test "x$with_libopenjpeg" = xno], [
190 libopenjpeg_missing=untried
191 ], [
192 libopenjpeg_missing=
193
194 PKG_CHECK_MODULES([LIBJP2K], [libopenjp2 >= 2.0.0], [
195 AC_DEFINE([HAVE_LIBJP2K], 1, [Define to 1 if you have libopenjp2.])
196 ], [
197 AC_CHECK_LIB([openjp2], [opj_create_decompress], [:], [libopenjpeg_missing=library])
198 AC_CHECK_HEADERS([openjpeg-2.3/openjpeg.h openjpeg-2.2/openjpeg.h openjpeg-2.1/openjpeg.h openjpeg-2.0/openjpeg.h],
199 [AC_DEFINE_UNQUOTED([LIBJP2K_HEADER], [<$ac_header>], [Path to <openjpeg.h> header file.]) break],
200 [libopenjpeg_missing=headers]
201 )
202
203 AS_IF([test "x$libopenjpeg_missing" = x], [
204 AC_DEFINE([HAVE_LIBJP2K], 1, [Define to 1 if you have libopenjp2.]) AC_SUBST([LIBJP2K_LIBS], [-lopenjp2])
205 ], [
206 AS_IF([test "x$with_libopenjpeg" = xyes], AC_MSG_ERROR([libopenjp2 support requested but $libopenjpeg_missing not found]))
207 ])
208 ])
209 ])
210
211 AM_CONDITIONAL([HAVE_LIBJP2K], [test "x$libopenjpeg_missing" = x])
212
213 # Check whether to enable debugging
214 AC_MSG_CHECKING([whether to enable debugging])
215 AC_ARG_ENABLE([debug],
216 AS_HELP_STRING([--enable-debug], [turn on debugging [default=no]]))
217 AC_MSG_RESULT([$enable_debug])
218 if test x"$enable_debug" = x"yes"; then
219 CFLAGS="-g -Wall -DDEBUG -pedantic -Og -g3"
220 fi
221
222 case "$host_os" in
223 mingw32*)
224 AC_SUBST([GDI_LIBS], [-lgdi32])
225 CPPFLAGS="${CPPFLAGS} -D__USE_MINGW_ANSI_STDIO" ;;
226 esac
227
228 # Enable less verbose output when building.
229 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
230
231 # Checks for typedefs, structures, and compiler characteristics.
232 AC_TYPE_SIZE_T
233 AC_C_BIGENDIAN
234
235 AC_SUBST([APPLE_UNIVERSAL_BUILD], [0])
236 AC_SUBST([ENDIANNESS], [L_LITTLE_ENDIAN])
237
238 case "$ac_cv_c_bigendian" in
239 yes) AC_SUBST([ENDIANNESS], [L_BIG_ENDIAN]) ;;
240 universal) AC_SUBST([APPLE_UNIVERSAL_BUILD], [1]) ;;
241 esac
242
243 # Add the -Wl and --as-needed flags to gcc compiler
244 AC_MSG_CHECKING([whether compiler supports -Wl,--as-needed])
245 OLD_LDFLAGS="${LDFLAGS}"
246 LDFLAGS="-Wl,--as-needed ${LDFLAGS}"
247
248 AC_LINK_IFELSE([AC_LANG_PROGRAM()],
249 AC_MSG_RESULT([yes]),
250 LDFLAGS="${OLD_LDFLAGS}"; AC_MSG_RESULT([no])
251 )
252
253 # Checks for library functions.
254 AC_CHECK_FUNCS([fmemopen])
255 AC_CHECK_FUNC([fstatat])
256 AC_CHECK_FUNC([dirfd])
257
258 # Configuration files
259 AC_CONFIG_FILES([Makefile src/endianness.h src/Makefile prog/Makefile lept.pc])
260
261 # cmake configuration. Get versions from PACKAGE_VERSION.
262 AX_SPLIT_VERSION
263 AC_SUBST([VERSION_PLAIN], ["${PACKAGE_VERSION}"])
264 AC_SUBST([VERSION_MAJOR], [$(echo "$AX_MAJOR_VERSION" | $SED 's/^[[^0-9]]*//')])
265 AC_SUBST([VERSION_MINOR], [$AX_MINOR_VERSION])
266 AC_SUBST([VERSION_PATCH], [$(echo "$AX_POINT_VERSION" | $SED 's/^\([[0-9]][[0-9]]*\).*/\1/')])
267 INCLUDE_PATH=`eval echo $includedir`
268 AC_SUBST([INCLUDE_DIR], ["${INCLUDE_PATH}/leptonica"])
269 AC_SUBST([leptonica_OUTPUT_NAME], ["leptonica"])
270 AC_CONFIG_FILES(cmake/templates/LeptonicaConfig.cmake)
271 AC_CONFIG_FILES(cmake/templates/LeptonicaConfig-version.cmake)
272
273 # Create symlink
274 AC_PROG_LN_S
275
276 AC_OUTPUT